size: 2 KiB

  

const std = @import("std");
const Io = std.Io;
const t = std.testing;
const mem = std.mem;
const assert = std.debug.assert;
const zlua = @import("zlua");
const djot_lua = @embedFile("vendor/djot.lua/djot.lua");
const Djot = @This();
lua: *zlua.Lua,
/// Must call deinit() when done.
pub fn init(gpa: mem.Allocator) !Djot {
    var lua = try zlua.Lua.init(gpa);
    lua.openLibs();
    const djot = Djot{ .lua = lua };
    lua.doString(djot_lua) catch |err| {
        try djot.printError();
        return err;
    };
    lua.doString(@embedFile("Djot.lua")) catch |err| {
        try djot.printError();
        return err;
    };
    return djot;
}
/// Clean up after the lua VM
pub fn deinit(self: *const Djot) void {
    self.lua.deinit();
}
/// Caller owns returned memory
pub fn toHtml(self: *const Djot, gpa: mem.Allocator, djot_text: []const u8) ![]const u8 {
    // call the global function
    assert(try self.lua.getGlobal("djot_to_html") == .function);
    _ = self.lua.pushString(djot_text);
    self.lua.protectedCall(.{ .args = 1, .results = 1 }) catch |err| {
        try self.printError();
        return err;
    };
    const output = self.lua.toString(-1) catch |err| {
        try self.printError();
        return err;
    };
    const result = gpa.dupe(u8, output);
    // All done. Pop previous result from stack.
    self.lua.pop(1);
    return result;
}
pub fn writeHtml(self: *const Djot, writer: *Io.Writer, djot_text: []const u8) !void {
    // call the global function
    assert(try self.lua.getGlobal("djot_to_html") == .function);
    _ = self.lua.pushString(djot_text);
    self.lua.protectedCall(.{ .args = 1, .results = 1 }) catch |err| {
        try self.printError();
        return err;
    };
    const output = self.lua.toString(-1) catch |err| {
        try self.printError();
        return err;
    };
    try writer.writeAll(output);
    // All done. Pop previous result from stack.
    self.lua.pop(1);
}
fn printError(self: *const Djot) !void {
    std.debug.print("lua error: {s}\n", .{try self.lua.toString(-1)});
}
test toHtml {
    const gpa = std.testing.allocator;
    const djot = try Djot.init(gpa);
    defer djot.deinit();
    const cases = .{
        .{ "*bold*", "<p><strong>bold</strong></p>\n" },
        .{
            "# foo",
            \\<section id="foo">
            \\<h1>foo</h1>
            \\</section>
            \\
        },
    };
    var writerBuf: [4096]u8 = undefined;
    inline for (cases) |case| {
        const input = case[0];
        const expected = case[1];
        // test toHtml
        const actual = try djot.toHtml(gpa, input);
        defer gpa.free(actual);
        try t.expectEqualStrings(expected, actual);
        // test writeHtml
        var writer = Io.Writer.fixed(&writerBuf);
        try djot.writeHtml(&writer, input);
        try t.expectEqualStrings(expected, writer.buffered());
        try writer.flush();
    }
}