size: 1 KiB

  

const std = @import("std");
const Io = std.Io;
const Post = @import("Post.zig");
const Meta = @import("Meta.zig");
const html = @import("html.zig");
pub const feed_path = "atom.xml";
pub fn atom(args: struct {
    arena: std.mem.Allocator,
    writer: *Io.Writer,
    meta: Meta,
    posts: []Post,
    now: []const u8,
}) !void {
    const w = args.writer;
    const arena = args.arena;
    try w.writeAll(
        \\<?xml version="1.0" encoding="utf-8"?>
        \\<feed xmlns="http://www.w3.org/2005/Atom">
        \\
    );
    try html.tag(w, "title", args.meta.site_name);
    try html.tag(w, "subtitle", args.meta.tagline);
    try w.print(
        \\<link href="{0s}/{1s}" rel="self" />
        \\<id>{0s}/</id>
        \\<updated>{2s}</updated>
        \\
    , .{
        args.meta.domain,
        feed_path,
        args.now,
    });
    for (args.posts) |p| {
        try w.print(
            \\<entry>
            \\  <id>{s}/{s}/</id>
            \\  <title>{s}</title>
            \\  <updated>{s}</updated>
            \\</entry>
            \\
        , .{
            args.meta.domain,
            try html.escapeAlloc(arena, p.slug),
            try html.escapeAlloc(arena, p.title),
            try html.escapeAlloc(arena, p.published_at),
        });
    }
    try w.writeAll(
        \\</feed>
        \\
    );
}